<<

NAME

Imager::Color - Color handling for Imager.

SYNOPSIS

  use Imager;

  $color = Imager::Color->new($red, $green, $blue);
  $color = Imager::Color->new($red, $green, $blue, $alpha);
  $color = Imager::Color->new("#C0C0FF"); # html color specification

  $color->set($red, $green, $blue);
  $color->set($red, $green, $blue, $alpha);
  $color->set("#C0C0FF"); # html color specification

  ($red, $green, $blue, $alpha) = $color->rgba();
  @hsv = $color->hsv();

  $color->info();

  if ($color->equals(other=>$other_color)) {
    ...
  }

DESCRIPTION

This module handles creating color objects used by Imager. The idea is that in the future this module will be able to handle color space calculations as well.

An Imager color consists of up to four components, each in the range 0 to 255. Unfortunately the meaning of the components can change depending on the type of image you're dealing with:

• for 3 or 4 channel images the color components are red, green, blue, alpha.
• for 1 or 2 channel images the color components are gray, alpha, with the other two components ignored.

An alpha value of zero is fully transparent, an alpha value of 255 is fully opaque.

METHODS

new

This creates a color object to pass to functions that need a color argument.

set

This changes an already defined color. Note that this does not affect any places where the color has been used previously.

rgba()

This returns the red, green, blue and alpha channels of the color the object contains.

info

Calling info merely dumps the relevant color to the log.

equals(other=>$other_color)

equals(other=>$other_color, ignore_alpha=>1)

Compares $self and color $other_color returning true if the color components are the same.

Compares all four channels unless ignore_alpha is set. If ignore_alpha is set only the first three channels are compared.

You can specify colors in several different ways, you can just supply simple values:

• simple numeric parameters - if you supply 3 or 4 numeric arguments, you get a color made up of those RGB (and possibly A) components.
• a six hex digit web color, either RRGGBB or #RRGGBB
• an eight hex digit web color, either RRGGBBAA or #RRGGBBAA.
• a 3 hex digit web color, #RGB - a value of F becomes 255.
• a color name, from whichever of the gimp Named_Colors file or X rgb.txt is found first. The same as using the name keyword.

You can supply named parameters:

• 'red', 'green' and 'blue', optionally shortened to 'r', 'g' and 'b'. The color components in the range 0 to 255.

   # all of the following are equivalent
   my $c1 = Imager::Color->new(red=>100, blue=>255, green=>0);
   my $c2 = Imager::Color->new(r=>100, b=>255, g=>0);
   my $c3 = Imager::Color->new(r=>100, blue=>255, g=>0);

• hue, saturation and value, optionally shortened to h, s and v, to specify a HSV color. 0 <= hue < 360, 0 <= s <= 1 and 0 <= v <= 1.

    # the same as RGB(127,255,127)
    my $c1 = Imager::Color->new(hue=>120, v=>1, s=>0.5);
    my $c1 = Imager::Color->new(hue=>120, value=>1, saturation=>0.5);

• web, which can specify a 6 or 3 hex digit web color, in any of the forms #RRGGBB, #RGB, RRGGBB or RGB.

    my $c1 = Imager::Color->new(web=>'#FFC0C0'); # pale red

• gray or grey which specifies a single channel, from 0 to 255.

    # exactly the same
    my $c1 = Imager::Color->new(gray=>128);
    my $c1 = Imager::Color->new(grey=>128);

• rgb which takes a 3 member arrayref, containing each of the red, green and blue values.

    # the same
    my $c1 = Imager::Color->new(rgb=>[255, 100, 0]);
    my $c1 = Imager::Color->new(r=>255, g=>100, b=>0);

• hsv which takes a 3 member arrayref, containing each of hue, saturation and value.

    # the same
    my $c1 = Imager::Color->new(hsv=>[120, 0.5, 1]);
    my $c1 = Imager::Color->new(hue=>120, v=>1, s=>0.5);

• gimp which specifies a color from a GIMP palette file. You can specify the file name of the palette file with the 'palette' parameter, or let Imager::Color look in various places, typically $HOME/gimp-1.x/palettes/Named_Colors with and without the version number, and in /usr/share/gimp/palettes/. The palette file must have color names.

    my $c1 = Imager::Color->new(gimp=>'snow');
    my $c1 = Imager::Color->new(gimp=>'snow', palette=>'testimg/test_gimp_pal);

• xname which specifies a color from an X11 rgb.txt file. You can specify the file name of the rgb.txt file with the palette parameter, or let Imager::Color look in various places, typically /usr/lib/X11/rgb.txt.

    my $c1 = Imager::Color->new(xname=>'blue') # usually RGB(0, 0, 255)

• builtin which specifies a color from the built-in color table in Imager::Color::Table. The colors in this module are the same as the default X11 rgb.txt file.

    my $c1 = Imager::Color->new(builtin=>'black') # always RGB(0, 0, 0)

• name which specifies a name from either a GIMP palette, an X rgb.txt file or the built-in color table, whichever is found first.
• 'channel0', 'channel1', etc, each of which specifies a single channel. These can be abbreviated to 'c0', 'c1' etc.
• 'channels' which takes an arrayref of the channel values.

Optionally you can add an alpha channel to a color with the 'alpha' or 'a' parameter.

These color specifications can be used for both constructing new colors with the new() method and modifying existing colors with the set() method.

METHODS

hsv()

    my($h, $s, $v, $alpha) = $color->hsv();

Returns the color as a Hue/Saturation/Value/Alpha tuple.

AUTHOR

Arnar M. Hrafnkelsson, addi@umich.edu And a great deal of help from others - see the README for a complete list.

SEE ALSO

Imager(3), Imager::Color http://imager.perl.org/

<<